Tag Archives: Evernote

記事

Everword 1.1を公開しました

2012/01/11 – 7:55 PM

Everword バージョン1.1を公開しました。

主な変更は共有ノートブックのサポートです。アプリ内課金時のみ共有ノートブックを利用できます。

Tags , | Comment (0)
記事

iPhoneアプリ「Everword – Evernote暗記カード」を公開しました

2011/12/14 – 6:55 AM

Evernoteを利用して暗記学習を行うためのiPhoneアプリ「Everword – Evernote暗記カード」を公開しました。

Evernoteのノートブックを登録して、ノートブックにあるノートをカード形式で表示して暗記学習をするためのアプリです。

Evernoteのノートは複雑な書式が使えるので、単純なノートの英単語の暗記から複雑なノートが必要な専門分野の知識の記憶まで可能です。Evernoteに情報を集約することになるので、情報の活用の幅が広がります。

私は英語の書籍を読む時に、分からない単語をEvernoteに入れていって、辞書アプリから単語の意味をコピーしてノートを作り、それをこのEverwordで学習しています。

また、習熟度別で3日後7日後など出題間隔が開くので、効率的な学習が出来ます。

無料ですので、ぜひ試しにダウンロードしてみてください。

無料ではノートブックの登録が一つに制限され、広告が表示されるという制約があります。アプリ内課金で250円支払っていただくと、ノートブックの登録制限と広告の表示が解除されます。複数のノートブックを使った方が、学習内容をよりマネージメントしやすくなります。

Tags , , | Comment (0)
Log

Evernoteのアカウント名を変更

2011/11/22 – 2:41 PM

Evernoteのアカウント名を変更した。

プレミアム会員のみアカウント名を変更してもらえる。今月25日に切れる契約だったので、ちょうどよかった。

サポートに変更のメッセージを送る→バックアップをとるように返信が来る→バックアップをとってリプライ→変更確認のメールが来る→変更希望を伝える→変更完了作業が行われる。

実際にはバックアップを利用することはなく、データは正常に受け継がれた。

無料会員は自分で新規アカウントを作ってデータをバックアップからリストアするというちょっと手間な作業が必要。

Tags | Comment (0)
記事

Evernote Safari5.1 Web クリッパーが公開された

2011/10/06 – 8:44 PM

Evernote Safari Web クリッパー公開 « Evernote日本語版ブログ: “Safari のエクステンション Evernote Web クリッパーが Apple Extension Gallery で公開されました。Apple からダウンロード または Evernote から直接ダウンロード。”

やっとEvernoteのWebクリッパーエクステンションが公開されました。Chromeの機能拡張に近い機能を持っているようです。

が、PDFで保存することはできなくなったようです。PDFで保存したい場合はSafari5.1からEvernoteにページをPDFで保存する方法を試してみてください。

Tags , | Comment (0)
記事

Safari5.1からEvernoteにページをPDFで保存する方法

2011/09/26 – 10:26 PM

Safari5.1になってEvernoteプラグインが機能しなくなって久しいですが、いまだ新版はリリースされません（と、書いているとリリースされたりして）。

なので、プリントダイアログからEvernoteにPDFで保存を実行すればできますが、SafariからEvernoteにPDFで保存するのが面倒になりました。

それをAppleScriptで簡単にしてしまおうというのがこの投稿の趣旨です。

で、そのAppleScriptスクリプトですが、以前に色々なアプリケーションからPDFとしてEvernoteに保存するAppleScriptで投稿済みだったりします。SafariだけでなくGoogle Chromeやその他のアプリからも保存が可能です。このスクリプトをSparkやLaunchBarなどから実行すれば、自動的にPDFがEvernoteに保存されます。また、アプリケーションとして保存すれば、Dockに登録して使うこともできます。

ということで、再度掲載しておきます。

-- LaunchBarから実行する場合は以下を有効にする
-- tell application "LaunchBar" to hide
 
tell application "System Events"
	-- AppleScript Editorから実行する場合は以下の2行を有効にする
	-- set theName to name of the first process whose frontmost is true
	-- set visible of process theName to false
	set theName to name of the first process whose frontmost is true
end tell
 
tell application theName to activate
 
if theName is "Google Chrome" then
	printPDF2EvernoteChrome(theName)
else
	printPDF2Evernote(theName)
end if
 
on printPDF2EvernoteChrome(theName)
	tell application "System Events" to tell process theName
		try
			keystroke "p" using command down
			repeat until exists menu button named "PDF" of window 1
				delay 0.2
			end repeat
			tell window 1
				click menu button "PDF"
				repeat until exists menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
					delay 0.2
				end repeat
				click menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
			end tell
		end try
	end tell
end printPDF2EvernoteChrome
 
on printPDF2Evernote(theName)
	tell application "System Events" to tell process theName
		try
			keystroke "p" using command down
 
			repeat 20 times
				if exists menu button named "PDF" of sheet 1 of window 1 then exit repeat
				delay 0.2
			end repeat
 
			tell sheet 1 of window 1
				click menu button "PDF"
 
				repeat 20 times
					if exists menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF" then exit repeat
					delay 0.2
				end repeat
				click menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
			end tell
		end try
	end tell
end printPDF2Evernote
Tags , , | Comment (1)
Log

Safari5.1でEvernoteクリッパープラグインが使えないのでブックマークを使用する

2011/07/25 – 11:43 AM

Safari5.1になってEvernoteクリッパープラグインが使えなくなっていますね。

しかたがないので､そのうち対応されることでしょうからそれまでの間はブックマークレットを使用してクリップすることにします。

追記: Safari 5.1からEvernoteにPDFで保存する方法について記事を書きました。

Tags , | Comments (3)
記事

色々なアプリケーションからPDFとしてEvernoteに保存するAppleScript

2011/05/13 – 3:06 PM

Google ChromeからPDFをEvernoteに保存するスクリプトを作成しましたが、同様に他のアプリからも簡単にEvernoteにPDFとして保存したい場合は以下のようなスクリプトになります。一般的なプリントダイアログを利用するアプリであれば利用できると思います。

[追記 2011/05/13] ループ等を修正しました。
[追記 2011/05/13] Chromeへの対応

-- LaunchBarから実行する場合は以下を有効にする
-- tell application "LaunchBar" to hide
 
tell application "System Events"
	-- AppleScript Editorから実行する場合は以下の2行を有効にする
	-- set theName to name of the first process whose frontmost is true
	-- set visible of process theName to false
	set theName to name of the first process whose frontmost is true
end tell
 
tell application theName to activate
 
if theName is "Google Chrome" then
	printPDF2EvernoteChrome(theName)
else
	printPDF2Evernote(theName)
end if
 
on printPDF2EvernoteChrome(theName)
	tell application "System Events" to tell process theName
		try
			keystroke "p" using command down
			repeat until exists menu button named "PDF" of window 1
				delay 0.2
			end repeat
			tell window 1
				click menu button "PDF"
				repeat until exists menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
					delay 0.2
				end repeat
				click menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
			end tell
		end try
	end tell
end printPDF2EvernoteChrome
 
on printPDF2Evernote(theName)
	tell application "System Events" to tell process theName
		try
			keystroke "p" using command down
 
			repeat 20 times
				if exists menu button named "PDF" of sheet 1 of window 1 then exit repeat
				delay 0.2
			end repeat
 
			tell sheet 1 of window 1
				click menu button "PDF"
 
				repeat 20 times
					if exists menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF" then exit repeat
					delay 0.2
				end repeat
				click menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
			end tell
		end try
	end tell
end printPDF2Evernote
Tags , , | Comment (0)
記事

Google ChromeからEvernoteにページをPDFで保存するAppleScript

2011/05/13 – 2:25 PM

–
色々なアプリケーションからPDFとしてEvernoteに保存するAppleScriptでより汎用的なスクリプトを公開しています。
–

SafariでページをPDFとしてEvernoteに保存するのは簡単ですが、Google Chromeではプリントメニューを表示してPDFボタンをクリックしてPDFをEvernoteに保存をクリックしなければPDFとしてEvernoteに保存することができません。

のでChromeからEvernoteにページをPDFで自動保存するAppleScriptを作成しました。

準備として、システム環境設定の「ユニバーサルアクセス」にある「補助装置にアクセスできるようにする」をオンにしてください。

以下がスクリプトです。このスクリプトをスクリプトエディタで保存して、スクリプトメニューから実行するなりLaunchBarやQuicksilverから実行するなりすれば、Chromeで開いているページをPDFとしてEvernoteに保存できます。

tell application "Google Chrome" to activate
tell application "System Events" to tell process "Google Chrome"
	click menu item named "印刷…" of menu 1 of menu bar item named "ファイル" of menu bar 1 --	keystroke "p" using command down	
	repeat until exists menu button named "PDF" of window 1
		delay 0.2
	end repeat
	tell window 1
		click menu button "PDF"
		repeat until exists menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
			delay 0.2
		end repeat
		click menu item named "PDFをEvernoteに保存" of menu 1 of menu button "PDF"
	end tell
end tell
Tags , , | Comment (0)
記事

Evernote 2.2 Beta1でついにノートリンク機能が追加

2011/05/13 – 9:58 AM

Evernote 2.2 Beta1 for Macでノートリンク機能が追加されました。
これはノートのURLを取得して、利用することができる機能です。

メニュー:編集→ノートリンクを実行すると、選択中のノートのURLを取得することができます。これをノートや他のアプリで利用することができます。

リンクをノートに貼り付けると、ノートのタイトルが表示されて、属性としてリンクが付きます。

ノート間で行ったり来たりできるようになるので、より使いやすいノートを作成することができるようになります。

他のアプリからもノートを参照できるようになるので、たとえばOmniFocusのタスクからEvernoteのノートを参照することもできるようになるので。さらにEvernoteの利用法が広がりそうです。

リンクは「evernote:///view/1307184/s11/a9bc7f7c-31cd-4767-9959-91201f75726a/a9bc7f7c-31cd-4767-9959-91201f75726a/」の形式になるので、Webインターフェースからこのリンクをクリックすると、Macクライアントが起動してノートが表示されます。Webインターフェース内での移動にはならないので注意が必要です。

ちなみに新しいノートは同期するか、ローカルノートブックに属していないとリンクが取得できません。

現在はAppleScriptからはノートリンクは取得できないようです。将来的には取得できるようになってほしいですね。

Tags , , | Comment (0)
記事

OmniFocusとEvernoteを連携させるAppleScript

2010/10/04 – 9:49 AM

以前からOmniFocusとEvernoteの連携で、EvernoteのノートURIが存在しないのできないと考えていたのですが、OmniFocusのタスクのURIは取得できるので、それを使えばいいじゃないかということで、いくつかAppleScriptを書いてみました。

まず、Evernoteノートを作成するスクリプトです。
新規にノートを作成して、タイトルにタスクのname、ソースURLにタスク（プロジェクト/フォルダ）URIを記入、タグにプロジェクト名を設定、本文にタスクURIとOmniFocusタスクのノートを記入します。本文にもURIを記入するのは、EvernoteでのソースURLの検索方法が無いみたいだからです。

tell front window of application "OmniFocus"
	try
		set theTrees to selected trees of content
 
		if (count of theTrees) < 1 then
			set theTrees to selected trees of sidebar
		end if
 
		if (count of theTrees) < 1 then
			return
		end if
 
		set theSelection to value of item 1 of theTrees
 
		if class of theSelection is folder then
			set theURI to "omnifocus:///folder/" & id of theSelection
			set theNote to ""
		else if class of theSelection is project then
			set theURI to "omnifocus:///project/" & id of theSelection
			set theNote to ""
		else
			set theURI to "omnifocus:///task/" & id of theSelection
			set theNote to note of theSelection
			set theProjectName to name of containing project of theSelection
		end if
 
		set theName to name of theSelection
 
		tell application "Evernote"
			set newNote to create note with text theURI & return & theNote
			set title of newNote to theName
			set source URL of newNote to theURI
 
			if (count of theProjectName) > 0 then
				if (not (tag named theProjectName exists)) then
					make tag with properties {name:theProjectName}
				end if
 
				set theTag to tag named theProjectName
				assign theTag to newNote
			end if
 
			open note window with newNote
			activate
		end tell
	end try
end tell

次にタスクURIをクリップボートに取得するスクリプトです。取得したURIは、既に存在するEvernoteノートに貼り付けるといいです。ソースURLにだけでなく、本文にも貼り付けておかないとURIで検索できません。

tell front window of application "OmniFocus"
	try
		set theTrees to selected trees of content
 
		if (count of theTrees) < 1 then
			set theTrees to selected trees of sidebar
		end if
 
		if (count of theTrees) < 1 then
			return
		end if
 
		set theSelection to value of item 1 of theTrees
 
		if class of theSelection is folder then
			set the clipboard to "omnifocus:///folder/" & id of theSelection
		else if class of theSelection is project then
			set the clipboard to "omnifocus:///project/" & id of theSelection
		else
			set the clipboard to "omnifocus:///task/" & id of theSelection
		end if
	end try
end tell

そして、上記二つのスクリプトで作成したEvernoteをタスクURIで検索するためのスクリプトです

tell front window of application "OmniFocus"
	try
		set theTrees to selected trees of content
 
		if (count of theTrees) < 1 then
			set theTrees to selected trees of sidebar
		end if
 
		if (count of theTrees) < 1 then
			return
		end if
 
		set theSelection to value of item 1 of theTrees
 
		if class of theSelection is folder then
			set theURI to "omnifocus:///folder/" & id of theSelection
		else if class of theSelection is project then
			set theURI to "omnifocus:///project/" & id of theSelection
		else
			set theURI to "omnifocus:///task/" & id of theSelection
		end if
 
		tell application "Evernote"
			open collection window with query string theURI
			activate
		end tell
	end try
end tell

EvernoteでURLの検索ができればいいのですが…。

ついでに、OmniFocusのプロジェクト名をEvernoteタグにしているので、プロジェクト名でタグを検索するスクリプトです。なんでもNozbeではプロジェクト名とEvernoteのタグが連動するらしいので、同様の機能をAppleScriptで実現しました。複数プロジェクト名での検索には対応してません。

tell front window of application "OmniFocus"
	try
		set theTrees to selected trees of content
 
		if (count of theTrees) < 1 then
			set theTrees to selected trees of sidebar
		end if
 
		set theSelection to value of item 1 of theTrees
 
		if class of theSelection is folder then
			set theQuery to "tag:" & name of theSelection
		else if class of theSelection is project then
			set theQuery to "tag:" & name of theSelection
		else
			set theProject to containing project of theSelection
 
			if theProject is equal to missing value then
				return
			end if
 
			set theQuery to "tag:" & name of theProject
		end if
 
		tell application "Evernote"
			open collection window with query string theQuery
			activate
		end tell
	end try
end tell

どのスクリプトもできたてホヤホヤでテストが不十分ですので、バグがあればコメントよろしくです。

Tags , , | Comment (0)

次ページへ »

次ページへ »

Get Adobe Flash playerPlugin by wpburn.com wordpress themes